Vytvoření Close Air Support

Tento skript vytvoří ve výchozím nastavení BLUFOR letoun, pilota a bod trasy, který má dá za úkol hledat nepřítele a ničit ho. K vytvoření dojde tři kilometry daleko od předané pozice, která tvoří jedinou povinnou položku volání. Dalšími volitelnými položkami je možné změnit stranu, typ letounu, pilota, nastavit případného střelce a výšku, ve které má létat. Zavolání skriptu pak vrátí objekt vytvořeného vozidla se kterým je možná následně pracovat.

celo_proc_cas_mission = {	
	params ["_x","_y","_z",["_side",WEST],["_vehicle","B_Plane_Fighter_01_Stealth_F"],["_pilot","B_Fighter_Pilot_F"],["_gunner",""],["_height",500]];
	private ["_logic","_init_plane_position","_support_plane","_gunner_unit"];
	_logic = "Logic" createVehicleLocal [_x,_y,0];
	_init_plane_position = _logic getRelPos [3000,(random 360)];
	_support_plane = createVehicle [_vehicle, _init_plane_position, [], 0, "FLY"];
	_support_plane addEventHandler ["Fired",{ _this#0 setVehicleAmmo 1 }];	 
	_pilots = [[0,0,_height], _side, [_pilot]] call BIS_fnc_spawnGroup;
	((units _pilots)#0) moveInDriver _support_plane;
	if (_gunner!="") then {
		_gunner_unit = _pilots createUnit [_gunner,[0,0,_height],[],0,"FORM"];
		_gunner_unit moveInGunner _support_plane;
	};        
	_support_plane flyInHeight _height;
	 
	_wp = _pilots addWaypoint [[_x,_y,_z],0];
	_wp setWaypointType "SAD";
	_wp setWaypointLoiterRadius 3000;
	_wp setWaypointLoiterType "CIRCLE_L";
	_wp setWaypointBehaviour "AWARE";
	_wp setWaypointCombatMode "RED";

	deleteVehicle _logic;
	_support_plane
};

Příklady volání:

(getpos player) spawn celo_proc_cas_mission; // nejsnazší volání
(getpos player) remoteExec ["celo_proc_cas_mission",2]; // vyvolani jen na serveru
(getpos player)+[EAST,"O_Plane_CAS_02_F","O_Fighter_Pilot_F"] spawn celo_proc_cas_mission; // vytvoření OPFOR CAS letounu
(getpos player)+[WEST,"B_Heli_Attack_01_F","B_Helipilot_F","B_Helipilot_F",250] spawn celo_proc_cas_mission; // vytvoření útočné helikoptéry s posádkou, včetně střelce, jenž bude létat v 250 metrech